String[] urlList;
BFont ft; 

float f_trx, f_try, f_rx, f_ry;
float f_tx = 320;
float f_ty = 180;
float f_x = -200;
float f_y = -200;

void setup(){
  size(640,360);
  background(255);
  rectMode(CENTER_DIAMETER);
  ellipseMode(CENTER_DIAMETER);
  //
  ft = loadFont("Univers46.vlw.gz"); 
  textFont(ft, 16); 

  //
  UrlChopper uc = new UrlChopper();
  String[] pagedata = loadPage("index.htm"); // get HTML data from target URL
  urlList = uc.getUrls(pagedata);
}

void loop(){
  background(255);
  translate(f_x, f_y,0);
  f_x +=(f_tx - f_x)*0.1;
  f_y +=(f_ty - f_y)*0.1;
  f_try = mouseY/float(height) * 6.28;
  f_trx = mouseX/float(width) * 6.28;
  f_rx += (f_trx - f_rx)*0.1;
  f_ry += (f_try - f_ry)*0.1;
  rotateY(f_rx);
  rotateX(f_ry);
  
  noStroke();
  stroke(100,100,100,150);
  fill(75,75,75,75);
  push();
  box(10,10,10);
  fill(150,50,50);
  rotateX(-f_ry);
  rotateY(-f_rx);
  text("index.htm", 0,15); 
  pop();
   
  float un = float(urlList.length);
  for(int i=0; i<un; i++){
    float r = ( 6.28 / float(un)*i);
    float x = cos(r)*120;
    float y = sin(r)*120;
    
    stroke(100,100,100,125);
    line(x,y,0,0);

    push();
    translate(x,y,0);
    stroke(100,100,100,150);
    fill(75,75,75,75);
    box(10,10,50);
    
    fill(150,50,50);
    translate(0,0,15);
    rotateX(-f_ry);
    rotateY(-f_rx);
    text(urlList[i], 0,0); 
    pop();
  }
}

String[] loadPage(String url){
  String lines[] = loadStrings(url);
  return lines;
}

//------------------------------------------------------------------------------------------------
//
//class UrlChopper
//
//ABOUT
//  using this class, you can get url link data from HTML.
//  just load a html file with loadStrings method.
//  and put it into getUrls() method, it returns a string array that contain url datas
//
//SAMPLECODE
//  String[] htmlList;
//  String[] urlList;
//  UrlChopper myUc = new UrlChopper();
//  htmlList = loadStrings("importer.php?url=xxxxxxxx");
//  urlList  = myUc.getUrls( htmlList );
//  for(int i=0; i<urlList.length; i++){
//    println(urlList[i]);
//  }
//
//FUNCTION
//  getUrls( String[] )
//  serch all url data from a string array and return a new string array that contains url
//
//NOTE
//  everyone just copy and use it.
//  who can make this better, please do it and lets make proce55ing world more fantastic :-);
//  and my english writing is poor, some one please fix my mistakes...
//
//THIS IS PROGRAMMED BY
// last updated 2003/DEC/8 by TAKA
//
// 1st editor: TAKA, http://www.vas-animatum.net
// 2nd editor:
// 3rd, 4th, 5th....
//------------------------------------------------------------------------------------------------

class UrlChopper{
  boolean _isdebug = true;
  UrlChopper(){
  }
  
  String[]  getUrls( String[] ls ){
    int ai;                                // index position of '<a href'
    String u;                              //url
    String l;                              // line data of html
    String[] urlList = new String[0];;     //array for url data 
  
    if(_isdebug){ println("--------------------------------------"); }  //when debug mode, print url
  
    for(int i=0; i< ls.length; i++){
      l = ls[i];
      ai = l.indexOf("<a href=");           // set a position of "<a href="
      while( ai != -1){                     // loop as long as <a> tags exhist
        u =  getUrl(l.substring(ai));       // get an url path
        urlList = addArray(urlList, u);     // add an url path to array;
        l = l.substring(ai + 7);            // shift serching position 
        ai = l.indexOf("<a href=");         // find next "<a href=" position
        
        if(_isdebug){ println(u); }         //when debug mode, print url
      }
    }
    return urlList;
  }
  
  //add data to an array
  String[] addArray( String[] ar, String str ){
    String[] newar = new String[ar.length + 1];
    for(int i=0; i < ar.length; i++){
      newar[i] = ar[i];
    }
    newar[ newar.length-1] = str;
    return newar;
  }
  
  // getUrl(string <a>tag)
  // get an urlpath from <a> tag
  String getUrl( String txt ){
    int sp, ep;

    sp = txt.indexOf("=");        // remove '<a href=' in front of url.
    txt = txt.substring(sp+1);
    txt = txt.trim();    
    
    sp = txt.indexOf('"');        // remove '"' in front of url.
    if( sp==0){
      txt = txt.substring(sp+1);
      txt = txt.trim();
    }
    
    ep = txt.indexOf(' ');        // remove ' ' behind url
    if( ep!=-1 ){
      txt = txt.substring(0,ep);
    }
    
    ep = txt.indexOf('>');        // remove '>' behind url
    if ( ep!=-1){
      txt = txt.substring(0,ep);
    }
    
    ep = txt.indexOf('"');        // remove '"' behind url
    if ( ep!=-1){
      txt = txt.substring(0,ep);
    }
    return txt;
  }
}

//------------------------------------------------------------------------------------------------